"Nu-Yu Silk&Lace" by "Anonymous Girly-Girl"
[(c) 2014 Anonymous, licensed under CC-NC-SA]

[
Nu-Yu famous makers of bodysuits that let you inhabit a new body temporarily has a new product out. It works a little differently but the effects are similar.
]

Include Unicode Full Character Names by Graham Nelson.

use no scoring.

Release along with a cover art ("woman in a white corset"), a website and an interpreter.

Chapter Rooms

Section Bathroom

The Hotel Bathroom is a room. The description is "A sparkling clean hotel bathroom with a [sink] and a [shower]."

The counter is a supporter in the bathroom.
The sink is in the bathroom. It is fixed in place.

Section Hotel Room

The Hotel Room is a room. "A luxurious Hotel Room with a large [queen bed], [fluffy pillows], and other assorted accouterments."
The hotel room is outside from the bathroom.

A queen bed is here. The description is "A queen size bed with laid out and fit for a queen!". The bed is fixed in place.
Some fluffy pillows are here. The description is "White fluffy pillows."

instead of going from the bathroom when the player is wet, say "You'll drip all over the carpet." instead.

Chapter Nu-Yu Kit Preamble
[Stuff referring to the Nu-Yu kit itself not it's contents] 

On the counter is a package. The description of the package is "Nu-Yu[unicode trade mark sign] Feminization Silk&Lace [unicode em dash] a new product from Nu-Yu[unicode trade mark sign] LLC.[line break]A fun way to feminize yourself temporarily."

The package is a closed openable container. The manual text is "Inside the Nu-Yu Feminization Kit are many items you can use to alter your appearence.[line break]Read more pages in the manual to get more information.[line break]Note: you will need to take most items out of the package before using them."

instead of taking the package, say "That will be awkward to carry."

report opening the package:
  say "You carefully reveal the contents of the package.[line break]Inside it are assorted clothing and cosmetic items, mostly in pink, purple, and white." instead;

Before listing contents:
	group conditioner bottles together as "different conditioners";
	group shampoo bottles together as "different shampoos";
	group bodywash bottles together as "different bodywashes";
	group lingerie together as "pieces of lingerie";

A thing has some text called the listed name. The listed name is usually "".

Rule for printing the name of something (called the thing that needs a name) while grouping together:
	if the listed name of the thing that needs a name is not "":
		say "[the listed name of the thing that needs a name]";
	otherwise:
		abide by the standard name printing rule for the thing that needs a name;

after examining the package when the package is not open, say "You can't wait to open it."

Before the player taking something when the noun is inside the package and the player is in the shower:
	say "You can't reach it from the shower." instead

Chapter Player Description

Section Hair

to say the description of the player's hair:
	let the conditioner be the conditioner bottle of the player;
	let the shampoo be the shampoo bottle of the player;
	say "[pre style of the shampoo][pre color of the conditioner] hair[post color of the conditioner][post style of the shampoo]";
	
Section Body Hair & Skin Color (body-wash traits)

A person can be hairy. The player is hairy.
Skin color is a kind of value. The skin colors are _pale, _olive, and _dark.
The player has a skin color. The skin color of the player is _pale.

to say the description of the player's skin:
	let bodywash be the bodywash bottle of the player;
	say "[if the player is not hairy]silky smooth [end if][skin color description of the bodywash] skin[if the player is hairy] covered in hair[end if]";

Section All Tighten/Loosen Traits

To decide what number is the currently chosen table row: (- ct_1 -).

Section Stomach/Waistline

Table of Stomach Size Descriptions
Description
"tightlaced"
["hourglass"] [doesn't fit the grammatical pattern well.]
"svelte"
"slender"
"skinny"
"neither skinny nor fat"
"pudgy"
"plump"
"heavyset"
"portly"
"corpulent"
"obese"
"whalelike"

The stomach size is a number that varies.
When play begins:
	Choose the row with a description of "neither skinny nor fat" in the table of stomach size descriptions;
	Now the stomach size is the currently chosen table row;

To say the description of the player's stomach:
	Choose row stomach size from the table of stomach size descriptions;
	say description entry;

Section Chest/Bosom

Table of Breast Size Descriptions
Description
"are flatchested"
"have budding breasts"
"have a modest bosom"
"are buxome"
"are busty"
"have an ample bosom"
["have excessive bosom"] [not feeling it]
"have breasts the size of melons"
"have breasts size of beachballs"

The breast size is a number that varies.
When play begins:
	Choose the row with a description of "are flatchested" in the table of breast size descriptions;
	Now the breast size is the currently chosen table row;

To say the description of the player's chest:
	Choose row breast size from the table of breast size descriptions;
	say description entry;	

Section Genitals

Table of Penis Size Descriptions
Description
"a little clitty"
"a girlcock"
"a small penis"
"an average sized penis"
"large penis"
"monster cock"

The penis size is a number that varies.
When play begins:
	choose the row with a description of "an average sized penis" in the table of penis size descriptions;
	Now the penis size is the currently chosen table row.

A person can be castrated. A person is usually not castrated.
Genitals are a kind of value. The genitals are penis and vagina.
The player has some genitals. The genitals of the player are usually penis.
	
To say the description of the player's genitals:
	Choose row penis size from the table of penis size descriptions;
	let has_vag be whether or not the genitals of the player is vagina;
	let has_balls be whether or not the player is not castrated;
	say "[description entry]";
	if has_balls is false and has_vag is true:
		if hairy:
			say " and a vagina underneath a big old muff";
		otherwise:
			say " and a vagina";
	otherwise if has_balls is true and has_vag is false:
		if hairy:
			say " and big hairy balls";
		otherwise:
			say " and balls";
	otherwise if has_balls is true and has_vag is true:
		if hairy:
			say " with a hairy balls and a vagina";
		otherwise:
			say " with balls and a vagina";
	otherwise:
		if hairy:
			say " atop a hairy, but otherwise empty, mons pubis";
		otherwise:
			say " atop an empty mons pubis.";

Section Sticky

A person can be sticky. A person is usually not sticky.

Every turn when the player was sticky:
	say "You're covered in a sticky substance. (gross)[line break]".

Section Putting it all together

instead of examining the player:
	say "You are [if the player is not wearing anything]naked[otherwise]wearing[a list of things worn by the player][end if].";
	say "You have [the description of the player's hair] and [the description of the player's skin].";
	say "You have [the description of the player's genitals].";
	say "You are [the description of the player's stomach] and [the description of the player's chest].";
	if the player is sticky, say "You're covered in some sticky substance, better rinse it off.";


Chapter Instruction Manual

A thing has some text called manual text. The manual text is usually "There's nothing written in the manual about that."
Reading the manual is an action applying to one thing.
Understand "manual [something]" as reading the manual.

Check reading the manual:
	if the manual is not held, say "You need to have the manual in order to read it." instead.
		
Carry out reading the manual: say "[the manual text of the noun][line break]"

A thing has some text called printing. The printing of a thing is usually "blank".
Understand the command "read" as something new. Understand "read [something preferably held]" as reading. Reading is an action applying to one carried thing. Check reading: if the printing of the noun is "blank", say "Nothing is written on the noun." instead. Carry out reading: say "You read: [printing of the noun][line break]". Report reading: do nothing.

After examining:
	If the the printing of the noun is not "blank", say "There's some text written on it."

The instruction manual is a thing in the package. The description is "'How to feminize yourself with the Nu-Yu Silk&Lace Feminization Kit'". The printing is "Type 'manual [italic type]object[roman type]' to read the page about that object." The manual text is "It'd be awfully weird if there were a page in the instruction manual about the instruction manual."


Chapter Ribbon & Castration

A castration implement is a kind of thing.
The ribbon is a castration implement in the package. The description of the ribbon is "Red silk ribbon." The manual text is "You can use this ribbon to castrate yourself painlessly." 

Castrating with is an action applying to one thing and one carried thing.
[Castrating with is an action applying to one carried thing.]
Understand "castrate [someone] with [something preferably held]", "castrate [someone]", and "castrate" as castrating with.
Understand "castrate with [something preferably held]" as castrating with.

Check castrating with:
	if the actor is not the player:
		say "You may only castrate yourself in this game." instead;
	otherwise if the second noun is not a castration implement:
		say "You must use a castration implement to castrate yourself." instead;

Carry out castrating with:
	Now the actor is castrated;
	Now the second noun is nowhere;

Report castrating with:
	say "You tie the silk ribbon in a bow around your testicles, close your eyes, brace yourself, and pull. It is totally painless, and when you open your eyes, your balls (and the ribbon) are gone.";

rule for supplying a missing noun while castrating with:
	now the noun is the player;

rule for supplying a missing second noun while castrating with:
	if the noun is a castration implement:
		now the second noun is the noun;
		now the noun is the player;
	otherwise:
		now the second noun is the ribbon;
		say "(with [the second noun])[command clarification break]";
	if the second noun is not carried:
		silently try taking the second noun;
		say "(first taking [the second noun])[command clarification break]";

instead of using the ribbon, try the player castrating with the ribbon.


Chapter Shower Items

A thing can be usable. A thing is usually not usable.
Using is an action applying to one carried thing.
understand "use [something preferably held]" as using.

check using something:
	if the noun is not held:
		say "You must be hold it to use it." instead;
	otherwise if the noun is not usable:
		say "You can't use that." instead;

A shower item is a kind of usable thing.		
check using a shower item:
	if the player is not in the shower:
		say "It'll drip all over the floor." instead;
	otherwise if the tap is not switched on:
		say "Now you're all sticky.";
		Now the player is sticky;
		stop the action.
	
	
Section Conditioner

A conditioner bottle is a kind of shower item.
Conditioner bottles have some text called pre color.
Conditioner bottles have some text called post color.
Conditioner bottles have some text called the bottle description.
Conditioner bottles have some text called the bottle printing.

The manual text of conditioner bottles is "Lather the conditioner in your hair for awhile then rinse, and your hair will be healthier and may change color. Read the bottle for a description of it's effects.".

The description of conditioner bottles is "A clear plastic bottle containing [bottle description].".
The printing of conditioner bottles is "[italic type][listed name in title case].[roman type][line break][bottle printing].".

Some conditioner bottles in the package are defined by the table of conditioner bottle descriptions.

Table of Conditioner Bottle Descriptions
Conditioner Bottle	listed name	pre color	post color	bottle description	bottle printing
a ginger conditioner bottle	"ginger"	"fiery red"	""	"translucent, viscous, reddish-orange liquid"	"If you don't have a soul, you can sin all you want"
a raven conditioner bottle	"raven"	"raven"	" as dark as night"	"pitch black liquid"	"Nevermore will you be lonely"
a blonde conditioner bottle	"blonde"	"blonde"	" that is magazine perfect"	"golden liquid"	"What gentleman prefer"
a brunette conditioner bottle	"brunette"	"lovely, brown"	""	"brown liquid the color of maple syrup"	"No need to mess with a classic"

The player has some conditioner bottle. The conditioner bottle of the player is usually the raven conditioner bottle.

carry out using a conditioner bottle (called the bottle):
	Now the conditioner bottle of the player is the bottle.
	
report using a conditioner bottle:
	say "You rub the contents of the [noun] into your hair and lather it up before rinsing it away.";
	say "Now you have [the description of the player's hair]";


Section Shampoo

A shampoo bottle is a kind of shower item.
Shampoo bottles have some text called the pre style.
Shampoo bottles have some text called the post style.
The manual text of shampoo bottles is "Lather the shampoo in your hair for awhile then rinse, and your hair will be cleaner and may change in length and volume. Read the bottle for a description of it's effects."

Some shampoo bottles in the package are defined by the table of shampoo bottle descriptions.

Table of Shampoo Bottle Descriptions
Shampoo Bottle	listed name	pre style	post style	description		printing
a long hair shampoo bottle	"long hair"	"long, flowing "	""	"An opaque pinkish bottle with a picture of a woman with long brown hair on it."	"Rupunzel! Rupunzel! Let down your hair."	
a short hair shampoo bottle	"short hair"	"short, spunky "	""	"An opaque purplish bottle with a picture of a woman with short bleach blonde hair."	"For the sportier, spunkier girl."
an afro shampoo bottle	"afro"	""	" in a big afro"	"An opaque golden brown bottle with a picture of a black woman with a big, beautiful afro."	"Hair is better [italic type]au naturale[roman type]." 

The buzz cut shampoo bottle is a shampoo bottle. The pre style is "buzzed, military-style". The post style is "".
The player has some shampoo bottle. The shampoo bottle of the player is usually the buzz cut shampoo bottle.

Carry out using a shampoo bottle:
	Now the shampoo bottle of the player is the noun;
	
Report using a shampoo bottle:
	say "You lather the [noun] into your hair.";
	say "Now you have [the description of the player's hair]."; 


Section Bodywash

A bodywash bottle is a kind of shower item.
Bodywash bottles have some text called the skin color description.
Bodywash bottles have some text called the bottle printing.
The manual text of bodywash bottles is "Apply the bodywash to a loofah sponge. Then spread the bodywash around your body. The bodywash will remove all your body hair and may change your complexion. Read the bottle for a description of it's effects."
The printing of bodywash bottles is "[italic type][listed name in title case][roman type]. [bottle printing]."

Some bodywash bottles in the package are defined by the table of bodywash bottle descriptions.

Table of Bodywash Bottle Descriptions
Bodywash	listed name	Skin Color Description	description	bottle printing
The alabaster skin bodywash	"alabaster"	"pale, alabaster"	"An opaque bottle with the torso of a woman with alabaster skin on it."	"Reflect the sun into your enemies eyes."	
The olive skin bodywash	"olive"	"olive"	"An opaque bottle with the torso of a very tan woman on it."	"That sun-kissed Mediterranean look." 
The ebony skin bodywash	"ebony"	"dark, chocolate colored"	"An opaque bottle with the torso of a black woman twisting to some imaginary beat."	"Skin that tastes like fudge."

The loofah sponge is a thing in the package. "A frilly pink loofah sponge." The manual text is "Needed to use bodywash correctly."

The player has some bodywash bottle. The bodywash bottle of the player is usually alabaster.

check using bodywash bottle:
	if the player does not have the loofah sponge:
		say "You need something else to  use this." instead;

carry out using a bodywash bottle:
	Now the player is not hairy;
	Now the bodywash bottle of the player is the noun;
	
report using a bodywash bottle:
	say "You lather up the loofah with [noun], and proceed to spread the suds around your body[if the player is hairy]. Body and facial hair fizzle away.[end if].";
	say "Now you are [the description of the player's skin].";


Chapter Shower 

A person can be wet. The player is not wet.

Every turn when the player is wet and the player is not in the shower:
	say "You're dripping wet."

The shower is an enterable container in the bathroom. It is fixed in place. The description is "How do they keep these showers so clean!".
The rack is a fixed in place supporter in the bathroom. The printed name is "towel rack".
On the rack is a towel. The towel is a usable thing.

drying off with is an action applying to one carried thing. 

understand "dry off", "dry myself/me off", "dry myself/me" as drying off with.
understand "dry off with [something preferably held]", "dry myself/me off with [something preferably held]", "dry myself/me with [something preferably held]" as drying off with.

rule for supplying a missing noun while drying off with:
	say "(with [the towel])[command clarification break]"; 
	now the noun is the towel;

check drying off with:
	if the noun is not the towel, say "You can't dry yourself off with that." instead;
	if the player is not wet, say "That's kind of pointless." instead;
 
carry out drying off with:
	Now the player is not wet.
		
report drying off with:
	say "You dry yourself off with [the towel]."
		
The tap is a device in the shower. It is fixed in place. The printed name is "shower tap". The description is "Turn the knob to let the hot water flow.".
Understand "knob" as tap. Understand "shower tap" as tap.

Instead of switching on the shower, try switching on the tap.
Instead of switching off the shower, try switching off the tap.

instead of switching on the tap when the player is in the shower:
	Now the player is wet;
	Now the player is not sticky;
	continue the action;
			
report switching on the tap:
	abide by the standard report switching on rule;
	if the player is in the shower:
		say "Warm water flows forth from the shower head onto your naked body.";
		if the player was sticky, say "The sticky substance rinses away.";
	otherwise:
		say "The water flows forth from the shower head.";
	stop the action;
	
report switching off the tap:
	abide by the standard report switching off rule;
	say "Water ceases to flow from the shower head.";
	stop the action;

instead of the player entering the shower when the tap is switched on:
	now the player is not sticky;
	now the player is wet;
	continue the action;

report the player entering the shower when the tap is switched on:
	abide by the standard report entering rule;
	if the player was sticky:
		say "The sticky substance rinses away.";
	if the player was not wet:
		say "Water flows over you getting you all wet.";
	abide by the describe contents entered into rule;
	stop the action;
	
[ instead of using...]

instead of using the towel, try drying off with the towel.
instead of using the shower, try switching on the tap.
instead of using the tap, try switching on the tap.
	
Chapter Lingerie & Tighten/Loosen

Lingerie is a kind of wearable thing.
Lingerie can be adjustable.
Tightening is an action applying to one carried thing. 
Loosening is an action applying to one carried thing.
Understand "tighten [something preferably held]" as tightening.
Understand "loosen [something preferably held]" as loosening.

check tightening:
	if the noun is not worn, say "You have to be wearing it [the noun]." instead;
	if the player is wet, say "You're all wet, you'll get it all wet." instead;

check loosening:
	if the noun is not worn,  say "You have to be wearing it [the noun]." instead;
	if the player is wet, say "You're all wet, you'll get it all wet." instead;
	
instead of using lingerie, try wearing the noun.
instead of wearing when the player is wet, say "You can't do that while you're wet." 

[ tighten/loosen all the way]

Tightening all the way is an action applying to one carried thing.
Understand "tighten [something preferably held] all the way" as tightening all the way.

Loosening all the way is an action applying to one carried thing.
Understand "loosen [something preferably held] all the way" as loosening all the way.

carry out tightening all the way:
	try silently tightening the noun;
	if the rule failed, stop the action;
	while the rule succeeded:
		try silently tightening the noun;
		
report tightening all the way:
	say "You tighten [the noun] all the way.";
	abide by the report tightening rules;
	
carry out loosening all the way:
	try silently loosening the noun; 
	if the rule failed, stop the action;
	while the rule succeeded:
		try silently loosening the noun;
		
report loosening all the way:
	say "You loosen [the noun] all the way.";
	abide by the report loosening rules;


Section Corset & Waist Cincher

The corset is adjustable lingerie in the package. The description is "White overbust corset." The manual text is "Tighten the corset to shrink your waist and grow your bust! Loosen to vice versa."

The waist cincher is an adjustable lingerie in the package. The description is "White waist cincher." The manual text is "Tighten to shrink your waist and loosen to get fatter."

Check the player wearing the waist cincher when the player is wearing the corset:
	say "You can't put on the waist cincher until you take off the corset." instead;
	
Check the player wearing the corset when the player is wearing waist cincher:
	say "You can't put on the corset until you take off the waist cincher." instead;

[ tightening the corset ]

this is the can't tighten corset any more rule:
	if the breast size plus one is greater than the number of rows in the table of breast size descriptions or the stomach size is 1:
		rule fails;

check tightening the corset:
	abide by the can't tighten corset any more rule;
	if the rule failed: 
		say "You can't tighten it any more." instead;

carry out tightening corset:
	increase breast size by one;
	decrease stomach size by one;

report tightening the corset:
	say "You tighten the laces, flesh shifts from your stomach to your chest.";
	say "You are now [the description of the player's stomach] and [the description of the player's chest].";

[ loosening the corset ]

check loosening the corset:
	if the stomach size plus one is greater than the number of rows in the table of stomach size descriptions or the breast size is 1:
		say "You can't loosen it any more." instead;

carry out loosening corset:
	decrease breast size by one;
	increase stomach size by one;

report loosening the corset:
	say "You loosen the laces, flesh shifts from your chest to your stomach.";
	say "You are now [the description of the player's stomach] and [the description of the player's chest].";

[ tightening the waist cincher ]

check tightening waist cincher:
	If the stomach size is 1:
		say "You can't tighten it any more." instead;
	
carry out tightening waist cincher:
	decrease the stomach size by one;
	
report tightening waist cincher:
	say "You tighten the laces of the cincher and your stomach shrinks.";
	say "You are now [the description of the player's stomach].";

[ loosening the waist cincher ]

check loosening waist cincher:
	if the stomach size plus one is greater than the number of rows in the table of stomach size descriptions:
		say "You can't loosen it any more." instead;

carry out loosening waist cincher:
	increase the stomach size by one.
	
report loosening waist cincher:
	say "You loosen the laces of the cincher and your stomach expands to fill the gap made.";
	say "You are now [the description of the player's stomach].";


Section Cock Sock

The cock sock is a privately-named adjustable lingerie in the package. The description is "Strange white sock with two red bows, one on top, and one on bottom."
The printed name is "strange sock". The manual text is "Put this sock (called a cock sock) on your penis, then adjust the length of your penis with the ribbons on the top and bottom.[line break]Pull them closer together for a shorter penis and farther apart for a longer one."
The cock sock can be examined. [The cock sock is usually not examined.]

after reading the manual the cock sock:
	Now the printed name of the cock sock is "cock sock";
	Now the description of the cock sock is "A sock for your cock, with two red bows, one on top, and one on bottom.";
	Now the cock sock is examined;

understand "strange sock" and "sock" as cock sock.
understand "cock sock" and "cocksock" as cock sock when the cock sock is examined.

[ tighten ]

check tightening the cock sock:
	if the penis size is one, say "There's just a little clitty left! You can't make it any smaller." instead;

carry out tightening the cock sock:
	decrease penis size by one;

report tightening the cock sock:
	say "You pull the ribbon at the head closer to the ribbon at the base.[line break]Mysteriously, your penis shrinks.";
	say "Now you have [the description of the player's genitals].";
	
[ loosen ]

check loosening the cock sock:
	if the penis size plus one is greater than the number of rows in the table of penis size descriptions:
		say "You struggle to stretch the sock out, but it won't go any bigger!" instead;

carry out loosening the cock sock:
	increase penis size by one;
	
report loosening the cock sock:
	say "You pull the ribbon at the head while holding the base.[line break]Amazingly, your penis get's larger.";
	say "Now you have [the description of the player's genitals].";


Section Stockings & Garter Belt
[
The stockings is lingerie in the package. The description is "White stockings with little red bows on it." The indefinite article is "some". The manual text is "Needed for the garter belt to work."

The garter belt is adjustable lingerie in the package. The description is "A cute little garter belt to go with the stockings." The manual text is "Tighen to become shorter, and loosen to become taller."

Check tightening the garter belt:
	if the player is not wearing stockings, say "The garter belt isn't attached to anything." instead.

Check loosening the garter belt:
	if the player is not wearing stockings, say "The garter belt isn't attached to anything." instead.
	
Carry out tightening the garter belt:
	do nothing; [TODO]
	
Carry out loosening the garter belt:
	do nothing; [TODO]
]


Section Lube & Dildo

In the package is some lube. The description of the lube is "A bottle of translucent pink 'personal' lubricant." The manual text of the lube is "Needed for the dildo to work.". 
The dildo is a usable thing in a the package. The description is "A pink & purple glass dildo." The manual text is "Use on your crotch to open up a vagina.".
understand "masturbate with [something preferably held]" as using.

understand "masturbate" as a mistake ("You could use your hands, but that doesn't sound like any fun. See if there's something you can masturbate with.").

Check using the dildo:
	if the player is not carrying the lube, say "You need the lube!" instead.
	
Carry out using the dildo:
	now the genitals of the player is vagina;

Report using the dildo:
	say "You spread the lube where the orifice should be and started caressing the area with the dildo. Layers of skin peel away to be come labia. You pressed the glass shaft between the folds and rubbing continuously [unicode em dash] each stroke going deeper and bringing more erotic pleasure. You nearly have the whole thing inside now.[paragraph break]With one final stroke, you screamed in pleasure with your first orgasm as a woman. Which was followed by another[unicode horizontal ellipsis] and another[unicode horizontal ellipsis] and another. As the waves of pleasure slowly subside as you come to your senses.";
	say "Now you have [the description of the player's genitals].";